@echo off

rem ----------------------------------------------
rem Smooth Manual Replace BAT
rem ----------------------------------------------

echo SMOOTHマニュアルを入れ替えます...

rem 変数定義
rem === マニュアルZIPファイル指定 ===
set zipFilePath=REMSManual_pdf.zip

rem === マニュアル展開先指定 ===
set deployDirPath=C:\HomeAsset\REMS

rem === マニュアル既存フォルダ ===
set ExistDirPath=C:\HomeAsset\REMS\REMSManual_pdf


rem === 既存フォルダの削除 ===
echo.
echo 既存のマニュアルを削除します...
if exist "%ExistDirPath%" (
    rmdir /s /q "%ExistDirPath%"
    if %errorlevel% neq 0 (
        echo.
        echo エラー: 既存フォルダの削除に失敗しました。
        echo 処理を中断します。
        goto :end
    )
    echo 既存フォルダの削除が完了しました。
) else (
    echo 既存フォルダ %ExistDirPath% は既に存在しません。スキップします。
)

rem === マニュアルPDFを解凍 ===
echo.
echo %zipFilePath% を %deployDirPath% に解凍します...
:: PowerShell を使用してzipを解凍します
set psCommand=powershell -NoProfile -ExecutionPolicy Unrestricted Expand-Archive -Path %zipFilePath% -DestinationPath %deployDirPath% -Force

rem PowerShellのコマンドレットを実行
%psCommand%

if %errorlevel% neq 0 (
    echo.
    echo エラー: zipファイルの解凍に失敗しました。
    goto :end
)
echo.
echo zipファイルの解凍が完了しました。

:end
echo.
echo 処理が終了しました。
pause
